無網路環境怎麼裝 Office 2024？ODT 離線打包與自動啟用實測分享 #Office2024 #Office2024LTSC #OfficeDeploymentTool #ODT #MicrosoftOffice #IT實戰 #系統維護 #自動化部署 #離線安裝 #BatchScript #批次檔 #什麼都做!~良

 

officedeploymenttool_17830-20162.exe 是微軟官方的 Office 部署工具（ODT, Office Deployment Tool）。

這套安裝流程預設需要連網，但可以透過兩階段操作實現完全離線安裝。

安裝機制說明

1. 主程式主體（需連網下載）： officedeploymenttool.exe 本身只是一個解壓縮檔。執行解壓後會得到 setup.exe 與幾個範例 .xml 設定檔，這些檔案裡面並不包含 Office 2024 的安裝檔本體。

2. 安裝時動作： 當你執行 setup.exe /configure configuration.xml 時，工具預設會連線到微軟 CDN 伺服器即時下載 Office 2024 LTSC Standard 的安裝包並進行安裝。

會提起這個主要是因為每次要安裝都需要連網安裝,但安裝要看它是連到伺服器來決定安裝速度,故研究一下要如何將安裝檔下載打包,之後就不用在費時等待下載時間,以滅少工作時間。


資料夾結構如下:

Office2024Setup/

├── setup.exe                  (微軟 ODT 工具)

├── configuration.xml          (設定檔)

├── Download_Office2024.bat     (先前提到的下載腳本)

├── Install_Office2024.bat      (剛建立的離線安裝腳本)

└── Office/                    (下載好的 2.5GB 數據包)

Step1.如下為離線下載安裝檔,Download_Office2024.bat,需搭配configuration.xml,要放在同一個目錄下載成功後會產生資料夾[Office]

================================================================

@echo off

chcp 65001 >nul

title 下載 Office 2024 Standard 完整離線安裝包

cd /d "%~dp0"

echo 正在連線至微軟 CDN 下載 Office 2024 Standard 離線安裝包...

echo 檔案大小約 2~3 GB，請保持網路連線並耐心等待。

echo.

setup.exe /download configuration.xml

if %errorlevel% equ 0 (

    echo.

    echo [成功] 離線安裝包已下載完成！

    echo 資料夾內已產生「Office」資料夾，請保留整個 Office2024Setup 資料夾備用。

) else (

    echo.

    echo [失敗] 下載過程出現錯誤，錯誤代碼: %errorlevel%

)

echo.

pause

===============================================================

Step2.如下為Install_Office2024.bat-->安裝使用，記得以「系統管理員身分」執行此批次檔

===============================================================

@echo off

chcp 65001 >nul

title Office 2024 Standard 離線安裝程序

net session >nul 2>&1

if %errorlevel% neq 0 (

    echo [提示] 請以「系統管理員身分」執行此批次檔！

    echo 請右鍵點擊此檔案，選擇「以系統管理員身分執行」。

    echo.

    pause

    exit /b

)

cd /d "%~dp0"

echo =====================================================

echo                      Office 2024 Standard 離線安裝

echo =====================================================

echo.

if not exist "%~dp0setup.exe" (

    echo [錯誤] 找不到 setup.exe！

    echo.

    pause

    exit /b

)

if not exist "%~dp0configuration.xml" (

    echo [錯誤] 找不到 configuration.xml！

    echo.

    pause

    exit /b

)

echo 正在執行 Office 2024 Standard 離線安裝...

echo 安裝視窗即將開啟，請稍候...

echo.

"%~dp0setup.exe" /configure "%~dp0configuration.xml"

if %errorlevel% equ 0 (

    echo.

    echo [成功] Office 2024 Standard 安裝已完成！

) else (

    echo.

    echo [失敗] 安裝出現錯誤，代碼: %errorlevel%

)

echo.

pause
===============================================================

Step3.最終安裝方法

離線安裝SOP

1.COPY資料夾至C:\Office2024Setup   

    -->我有試過加[.]會自動抓取放置路徑，但是會安裝失敗，故就用固定路徑！
    -->這個加[.]我用2019試正常可以運行,但2024不行!我就沒在研究下去了~

2.安裝請以系統管理員身份執行Install_Office2024.bat


補充：［configuration.xml］ 預設是沒有含序號，若要安裝指定序號可以參考如下自己修改: 修改["XXXXX-XXXXX-XXXXX-XXXXX-XXXXX" ]即可

===============================================================

<Configuration>

  <!-- 用 "." 代表相對路徑：直接讀取與 setup.exe 同一個資料夾 -->

  <Add SourcePath="C:\Office2024Setup" OfficeClientEdition="64" Channel="PerpetualVL2024">

    <Product ID="Standard2024Volume">

      <Language ID="zh-tw" />

      

      <!-- 自動帶入 Office 2024 Standard 25 位數序號 -->

      <Property Name="PIDKEY" Value="XXXXX-XXXXX-XXXXX-XXXXX-XXXXX" />

    </Product>

  </Add>

  <!-- 自動移除舊版 Office -->

  <RemoveMSI />

  <!-- 自動啟用設定 (1 表示安裝完成後若有網路會自動啟用) -->

  <Property Name="AUTOACTIVATE" Value="1" />

  <Display Level="Full" AcceptEULA="TRUE" />

</Configuration>

===============================================================